Этот сайт использует cookies. Продолжение работы с сайтом означает, что Вы согласны!
Основные функции для работы со строками
Рассмотрим основные функции для работы со строками:
Len(<Строка>)
— возвращает количество символов в строке:
Dim s As String
s = "Строка"
Debug.Print Len(s) ' 6
Trim(<Строка>)
— удаляет пробелы в начале и конце строки. Возвращает новую строку. Пример:
s = " Строка "
Debug.Print "'" & Trim(s) & "'" ' 'Строка'
Функция Trim()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию Trim$()
, имеющую тот же самый формат. Пример:
s = " Строка "
Debug.Print "'" & Trim$(s) & "'" ' 'Строка'
LTrim(<Строка>)
— удаляет пробелы в начале строки. Возвращает новую строку. Пример:
s = " Строка "
Debug.Print "'" & LTrim(s) & "'" ' 'Строка '
Функция LTrim()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию LTrim$()
, имеющую тот же самый формат. Пример:
s = " Строка "
Debug.Print "'" & LTrim$(s) & "'" ' 'Строка '
RTrim(<Строка>)
— удаляет пробелы в конце строки. Возвращает новую строку. Пример:
s = " Строка "
Debug.Print "'" & RTrim(s) & "'" ' ' Строка'
Функция RTrim()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию RTrim$()
, имеющую тот же самый формат. Пример:
s = " Строка "
Debug.Print "'" & RTrim$(s) & "'" ' ' Строка'
Mid(<Строка>, <Начало>[, <Длина>])
— возвращает фрагмент строки, начиная с позиции<Начало>
длиной<Длина>
символов. Нумерация символов в строке начинается с1
. Если в параметре<Начало>
указано число больше количества символов в строке, то возвращается пустая строка. Параметр<Длина>
задает длину фрагмента в символах. Если параметр не указан, то возвращается фрагмент до конца строки. Пример:
Debug.Print Mid("строка", 1) ' строка
Debug.Print Mid("строка", 1, 3) ' стр
Debug.Print Mid("строка", 2, 1) ' т
Функция Mid()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию Mid$()
, имеющую тот же самый формат. Пример:
Debug.Print Mid$("строка", 1, 3) ' стр
Если функция Mid()
расположена слева от оператора присваивания, то можно заменить фрагмент другой строкой. Если длина нового фрагмента больше длины старого фрагмента, то новый фрагмент будет обрезан. Пример:
Dim s As String
s = "строка"
Mid(s, 1, 1) = "7"
Debug.Print s ' 7трока
Mid(s, 1, 2) = "787"
Debug.Print s ' 78рока
Mid(s, 1, 2) = "9"
Debug.Print s ' 98рока
MidB(<Строка>, <Начало>[, <Длина>])
— возвращает фрагмент строки, начиная с позиции<Начало>
длиной<Длина>
байтов. ФункцияMidB()
аналогична функцииMid()
, но длина указывается на в символах, а в байтах, что позволяет использовать функцию для получения фрагмента бинарной строки. Пример:
Debug.Print MidB("строка", 1, 6) ' стр
Функция MidB()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию MidB$()
, имеющую тот же самый формат. Пример:
Debug.Print MidB$("строка", 1, 6) ' стр
Если функция MidB()
расположена слева от оператора присваивания, то можно заменить фрагмент другой строкой. Пример:
Dim s As String
s = "строка"
MidB(s, 1, 2) = "7"
Debug.Print s ' 7трока
Left(<Строка>, <Длина>)
— возвращает фрагмент строки, начиная с начала строки длиной<Длина>
символов. Параметр<Длина>
задает длину фрагмента в символах. Если параметр содержит значение равное или большее количества символов в строке, то возвращается фрагмент до конца строки. Пример:
Debug.Print Left("строка", 1) ' с
Debug.Print Left("строка", 4) ' стро
Debug.Print Left("строка", 9) ' строка
Функция Left()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию Left$()
, имеющую тот же самый формат. Пример:
Debug.Print Left$("строка", 4) ' стро
LeftB(<Строка>, <Длина>)
— функция аналогична функцииLeft()
, но длина указывается не в символах, а в байтах, что позволяет использовать функцию для получения фрагмента бинарной строки. Пример:
Debug.Print LeftB("строка", 4) ' ст
Функция LeftB()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию LeftB$()
, имеющую тот же самый формат. Пример:
Debug.Print LeftB$("строка", 4) ' ст
Right(<Строка>, <Длина>)
— возвращает фрагмент строки, начиная с конца строки длиной<Длина>
символов. Параметр<Длина>
задает длину фрагмента в символах. Если параметр содержит значение равное или большее количества символов в строке, то возвращается вся строка. Пример:
Debug.Print Right("строка", 1) ' а
Debug.Print Right("строка", 4) ' рока
Debug.Print Right("строка", 9) ' строка
Функция Right()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию Right$()
, имеющую тот же самый формат. Пример:
Debug.Print Right$("строка", 4) ' рока
RightB(<Строка>, <Длина>)
— функция аналогична функцииRight()
, но длина указывается не в символах, а в байтах, что позволяет использовать функцию для получения фрагмента бинарной строки. Пример:
Debug.Print RightB("строка", 4) ' ка
Функция RightB()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию RightB$()
, имеющую тот же самый формат. Пример:
Debug.Print RightB$("строка", 4) ' ка
Split()
— разделяет строку на подстроки по указанному разделителю и добавляет их в массив. Подробное описание этой функции приведено в разд. 2.9.6;Space(<Количество>)
— возвращает строку, состоящую из указанного количества пробелов:
Debug.Print "'" & Space(5) & "'" ' ' '
Функция Space()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию Space$()
, имеющую тот же самый формат. Пример:
Debug.Print "'" & Space$(5) & "'" ' ' '
String(<Количество>, <Строка или код символа>)
— возвращает строку, состоящую из указанного количества первого символа из заданной строки. Вместо строки можно указать код символа. Пример:
Debug.Print String(5, "N") ' NNNNN
Debug.Print String(5, "Npt") ' NNNNN
Debug.Print String(5, 78) ' NNNNN
Функция String()
возвращает значение типа Variant
(String)
. Чтобы получить значение типа String
следует использовать функцию String$()
, имеющую тот же самый формат. Пример:
Debug.Print String$(5, "N") ' NNNNN
StrReverse(<Строка>)
— меняет порядок следования букв в слове на противоположный. Возвращает новую строку. Пример:
Debug.Print StrReverse("строка") ' акортс
Помощь сайту
Yandex-деньги: 410011140483022
ПАО Сбербанк:
Счет: 40817810855006152256
Реквизиты банка:
Наименование: СЕВЕРО-ЗАПАДНЫЙ БАНК ПАО СБЕРБАНК
Корреспондентский счет: 30101810500000000653
БИК: 044030653
КПП: 784243001
ОКПО: 09171401
ОКОНХ: 96130
Скриншот реквизитов